【超簡単】 ESP32 を使って携帯でLEDを点灯する(Wifi使用）

アイコン名を入力

携帯でラジコンを動かしたりしてみたい。。。

携帯で操作できる電子回路に関する知識を身につけたい。。。IOTってどんなこと？？

こんな人に安価で便利なESP32を使用して携帯でLEDを点灯する方法を紹介します。非常に簡単で、応用が利くため、携帯でラジコンを操作したい等の参考になります。

ESP32というデバイスを使用すると、安価でBlue tooth やWifi接続が可能なため、携帯で遠隔から操作可能となり、いろいろなことができます。今回は超基礎のLEDのon-off方法を紹介します。

こんなものが作れるようになります。

Contents

ESP32とは
ESP32でLEDのOn-Offをするために必要なもの
ESP32のLED ON-OFF回路作成
ESP32 LED On-Offコード作成
1. 注意するところ
  - Wifiのssid, passを自分のネットワークに設定する
  - コードの中身

🚀 0円で現役エンジニアから学べる【Techスクールオンライン】のお申込みをお勧めします。このオンラインスクールでは、現役のエンジニアから直接学ぶことができ、プログラミングの基礎から高度なスキルまでを習得できます。しかも、今なら 0円で受講できるチャンスです。エンジニア転職を考えている方やプログラミングに興味がある方、新しいスキルを習得したい方に特におすすめです。

ESP32とは

ESP32とは1000円以下と安価で無線接続可能かつフラッシュメモリ4MBとなかなか高性能なデバイスになります。Arduinoだと、WifiやBluetoothの接続をしないといけないため、結構複雑になるのですが、こちらを使用すると簡単に無線接続ができるため、かなりおすすめです。

ESP32でLEDのOn-Offをするために必要なもの

ESP32 ボード

1000円程度で安価にWebサーバーが使えるようになるためおすすめです。さらにArduinoより小型となり便利です。

リンク

LED

LEDを準備してください。Arduinoのキットを購入するといろいろな部品が入っていておすすめです。

リンク

ブレッドボード

ブレッドボードにESP32が直接ささります。ただ、ブレッドボードの穴はピンで拡張されると思います。

リンク

抵抗, ジャンパ線

小物系はこちらのキットを購入するといいと思います

ESP32のLED ON-OFF回路作成

ではこれから回路を作成していきます。回路としてはLEDのOn-OFFを行うだけなのでかなりシンプルになります。下図のようにLEDとESP32を接続してください。

ESP32	ブレッドボード
GND	GND
D27	LED No1
D26	LED No2
D32	LED No3

回路接続先

回路を作成したら、次はコード作成になります。

ESP32 LED On-Offコード作成

LEDのOn-Offコードを作成するために、htmlでブラウザを作っています。プログラムはこちらのサイトを参考に作成しています。

https://randomnerdtutorials.com/esp32-web-server-arduino-ide/

#include <WiFi.h>

const char* ssid = "REPLACE_WITH_YOUR_SSID";
const char* password = "REPLACE_WITH_YOUR_PASSWORD";

// Set web server port number to 80
WiFiServer server(80);

// Variable to store the HTTP request
String header;

// Auxiliar variables to store the current output state
String output26State = "off";
String output27State = "off";

// Assign output variables to GPIO pins
const int output26 = 26;
const int output27 = 27;

// Current time
unsigned long currentTime = millis();
// Previous time
unsigned long previousTime = 0; 
// Define timeout time in milliseconds (example: 2000ms = 2s)
const long timeoutTime = 2000;

void setup() {
  Serial.begin(115200);
  // Initialize the output variables as outputs
  pinMode(output26, OUTPUT);
  pinMode(output27, OUTPUT);
  // Set outputs to LOW
  digitalWrite(output26, LOW);
  digitalWrite(output27, LOW);

  // Connect to Wi-Fi network with SSID and password
  Serial.print("Connecting to ");
  Serial.println(ssid);
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  // Print local IP address and start web server
  Serial.println("");
  Serial.println("WiFi connected.");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());
  server.begin();
}

void loop(){
  WiFiClient client = server.available();   // Listen for incoming clients

  if (client) {                             // If a new client connects,
    currentTime = millis();
    previousTime = currentTime;
    Serial.println("New Client.");          // print a message out in the serial port
    String currentLine = "";                // make a String to hold incoming data from the client
    while (client.connected() && currentTime - previousTime <= timeoutTime) {  // loop while the client's connected
      currentTime = millis();
      if (client.available()) {             // if there's bytes to read from the client,
        char c = client.read();             // read a byte, then
        Serial.write(c);                    // print it out the serial monitor
        header += c;
        if (c == '\n') {                    // if the byte is a newline character
          // if the current line is blank, you got two newline characters in a row.
          // that's the end of the client HTTP request, so send a response:
          if (currentLine.length() == 0) {
            // HTTP headers always start with a response code (e.g. HTTP/1.1 200 OK)
            // and a content-type so the client knows what's coming, then a blank line:
            client.println("HTTP/1.1 200 OK");
            client.println("Content-type:text/html");
            client.println("Connection: close");
            client.println();
            
            // turns the GPIOs on and off
            if (header.indexOf("GET /26/on") >= 0) {
              Serial.println("GPIO 26 on");
              output26State = "on";
              digitalWrite(output26, HIGH);
            } else if (header.indexOf("GET /26/off") >= 0) {
              Serial.println("GPIO 26 off");
              output26State = "off";
              digitalWrite(output26, LOW);
            } else if (header.indexOf("GET /27/on") >= 0) {
              Serial.println("GPIO 27 on");
              output27State = "on";
              digitalWrite(output27, HIGH);
            } else if (header.indexOf("GET /27/off") >= 0) {
              Serial.println("GPIO 27 off");
              output27State = "off";
              digitalWrite(output27, LOW);
            }
            
            // Display the HTML web page
            client.println("<!DOCTYPE html><html>");
            client.println("<head><meta name=\"viewport\" content=\"width=device-width, initial-scale=1\">");
            client.println("<link rel=\"icon\" href=\"data:,\">");
            // CSS to style the on/off buttons 
            // Feel free to change the background-color and font-size attributes to fit your preferences
            client.println("<style>html { font-family: Helvetica; display: inline-block; margin: 0px auto; text-align: center;}");
            client.println(".button { background-color: #4CAF50; border: none; color: white; padding: 16px 40px;");
            client.println("text-decoration: none; font-size: 30px; margin: 2px; cursor: pointer;}");
            client.println(".button2 {background-color: #555555;}</style></head>");
            
            // Web Page Heading
            client.println("<body><h1>ESP32 Web Server</h1>");
            
            // Display current state, and ON/OFF buttons for GPIO 26  
            client.println("<p>GPIO 26 - State " + output26State + "</p>");
            // If the output26State is off, it displays the ON button       
            if (output26State=="off") {
              client.println("<p><a href=\"/26/on\"><button class=\"button\">ON</button></a></p>");
            } else {
              client.println("<p><a href=\"/26/off\"><button class=\"button button2\">OFF</button></a></p>");
            } 
               
            // Display current state, and ON/OFF buttons for GPIO 27  
            client.println("<p>GPIO 27 - State " + output27State + "</p>");
            // If the output27State is off, it displays the ON button       
            if (output27State=="off") {
              client.println("<p><a href=\"/27/on\"><button class=\"button\">ON</button></a></p>");
            } else {
              client.println("<p><a href=\"/27/off\"><button class=\"button button2\">OFF</button></a></p>");
            }
            client.println("</body></html>");
            
            // The HTTP response ends with another blank line
            client.println();
            // Break out of the while loop
            break;
          } else { // if you got a newline, then clear currentLine
            currentLine = "";
          }
        } else if (c != '\r') {  // if you got anything else but a carriage return character,
          currentLine += c;      // add it to the end of the currentLine
        }
      }
    }
    // Clear the header variable
    header = "";
    // Close the connection
    client.stop();
    Serial.println("Client disconnected.");
    Serial.println("");
  }
}

今回は上記のコードを参考にLEDを３つに設定してみました。上記コードを使用して注意するところは下記になります。

注意するところ

Wifiのssid, passを自分のネットワークに設定する

コードの中身

if (header.indexOf("GET /26/on") >= 0) {
Serial.println("GPIO 26 on");
output26State = "on";
digitalWrite(output26, HIGH);

上記コードでブラウザ上でGPIO26のボタンがonとなった場合、ESP32の26ピンの設定をONにしています。

また下記コードでブラウザを作成しています。

ですので、先頭の①行でhtmlの設定とcss形式を記載しています。これにより、Webページのフォントやボタンのフォーマットを決定しています。

②でWebページのタイトルやボタンの名称などをつけて、Webページを作成しています。ですので、②の<body><h1>ESP32 Web Server</h1>の行でいう<h1></h1>で囲まれている間の”ESP32 Web Server”と入力している部分の文字を自由に記入したい名称とすることで、タイトルを変えることができます。一度やるとボタンの追加や名称変更などができますので、一度やってみてください。

// ①Display the HTML web page
client.println("<!DOCTYPE html><html>");
client.println("<head><meta name=\"viewport\" content=\"width=device-width, initial-scale=1\">");
client.println("<link rel=\"icon\" href=\"data:,\">");
// CSS to style the on/off buttons
// Feel free to change the background-color and font-size attributes to fit your preferences
client.println("<style>html { font-family: Helvetica; display: inline-block; margin: 0px auto; text-align: center;}");
client.println(".button { background-color: #4CAF50; border: none; color: white; padding: 16px 40px;");
client.println("text-decoration: none; font-size: 30px; margin: 2px; cursor: pointer;}");
client.println(".button2 {background-color: #555555;}</style></head>");

// ②Web Page Heading　タイトル・ボタンなどの設定
client.println("<body><h1>ESP32 Web Server</h1>");

// Display current state, and ON/OFF buttons for GPIO 26
client.println("<p>GPIO 26 - State " + output26State + "</p>");
// If the output26State is off, it displays the ON button
if (output26State=="off") {
client.println("<p><a href=\"/26/on\"><button class=\"button\">ON</button></a></p>");
} else {
client.println("<p><a href=\"/26/off\"><button class=\"button button2\">OFF</button></a></p>");
}

// Display current state, and ON/OFF buttons for GPIO 27
client.println("<p>GPIO 27 - State " + output27State + "</p>");
// If the output27State is off, it displays the ON button
if (output27State=="off") {
client.println("<p><a href=\"/27/on\"><button class=\"button\">ON</button></a></p>");
} else {
client.println("<p><a href=\"/27/off\"><button class=\"button button2\">OFF</button></a></p>");
}
client.println("</body></html>");

上記のコードを自由に変えるといろいろなESP32を使用して自由にWebページを作ることができ、温度測定やカメラ画像を遠隔から操作するなどもできるようになると思うので面白いと思います。

興味があったら、YOU TUBEを見てください。